Imports System.Collections.Specialized
Imports System.ComponentModel
Imports System.Web
Imports System.Web.UI
Imports System.Web.UI.WebControls

Namespace WebControls
    < _
    Description("核取方塊欄位") _
    > _
    Public Class TBCheckBoxField
        Inherits CheckBoxField

        Private FDefineValue As String = String.Empty

        ''' 

        ''' 布林值轉換定義，格式為 "True/False"。
        ''' 
        ''' 
        ''' 當設定為 "T/F" 時，表示 T 為 True，F 為 False。
        ''' 當設定為 "T/*" 時，表示 T 為 True，其他為 False。
        '''  
        Public Property DefineValue() As String
            Get
                Return FDefineValue
            End Get
            Set(ByVal value As String)
                FDefineValue = value
            End Set
        End Property

        ''' 

        ''' 解析布林值轉換定義。
        ''' 
        ''' 布林值轉換定義。
        ''' True 的對應值。
        ''' False 的對應值。
        Private Sub ParserDefineValue(ByVal DefineValue As String, ByRef TrueValue As String, ByRef FalseValue As String)
            Dim oParts() As String

            oParts = Split(Me.DefineValue, "/")
            If oParts.Length <> 2 Then
                Throw New HttpException("DefineValue 格式錯誤")
            End If
            TrueValue = oParts(0)
            FalseValue = oParts(1)
        End Sub

        ''' 

        ''' 欄位值依 DefineValue 的定義轉換為布林值。
        ''' 
        ''' 欄位值。
        Private Function ValueToBoolean(ByVal Value As Object) As Boolean
            Dim sFieldValue As String
            Dim sTrueValue As String
            Dim sFalseValue As String

            sFieldValue = CStr(Value)
            sTrueValue = String.Empty
            sFalseValue = String.Empty
            ParserDefineValue(Me.DefineValue, sTrueValue, sFalseValue)

            If sFieldValue = sTrueValue Then
                Return True
            Else
                Return False
            End If
        End Function

        ''' 

        ''' 布林值依 DefineValue 的定義轉換為欄位值。
        ''' 
        ''' 布林值。
        Private Function BooleanToValue(ByVal Value As Boolean) As Object
            Dim sTrueValue As String
            Dim sFalseValue As String

            sTrueValue = String.Empty
            sFalseValue = String.Empty
            ParserDefineValue(Me.DefineValue, sTrueValue, sFalseValue)

            If Value Then
                Return sTrueValue
            Else
                Return sFalseValue
            End If
        End Function


        ''' 

        ''' 將欄位值繫結至 TBCheckBoxField 物件中的核取方塊。 
        ''' 
        ''' 作用的控制項。
        ''' 事件引數。
        Protected Overrides Sub OnDataBindField(ByVal sender As Object, ByVal e As EventArgs)
            Dim oControl As Control = DirectCast(sender, Control)
            Dim oNamingContainer As Control = oControl.NamingContainer
            Dim oFieldValue As Object = Me.GetValue(oNamingContainer)

            If Not TypeOf oControl Is CheckBox Then
                Throw New HttpException("繫結的控制項非核取方塊")
            End If

            If IsDBNull(oFieldValue) Then
                DirectCast(oControl, CheckBox).Checked = False
            ElseIf TypeOf oFieldValue Is Boolean Then
                DirectCast(oControl, CheckBox).Checked = CBool(oFieldValue)
            Else
                If Not Me.DesignMode Then
                    Try
                        If Me.DefineValue <> String.Empty Then
                            DirectCast(oControl, CheckBox).Checked = ValueToBoolean(oFieldValue)
                        Else
                            DirectCast(oControl, CheckBox).Checked = CBool(oFieldValue)
                        End If
                    Catch exception As FormatException
                        Throw New HttpException("無法將值轉為布林值", exception)
                    End Try
                End If
            End If

            DirectCast(oControl, CheckBox).Text = Me.Text
        End Sub

        ''' 

        ''' 使用指定 DataControlFieldCell 物件的值填入指定的 System.Collections.IDictionary 物件。 
        ''' 
        ''' 用於儲存指定儲存格的值。
        ''' 包含要擷取值的儲存格。
        ''' 資料列的狀態。
        ''' true 表示包含唯讀欄位的值，否則為 false。
        Public Overrides Sub ExtractValuesFromCell(ByVal Dictionary As IOrderedDictionary, ByVal Cell As DataControlFieldCell, _
            ByVal RowState As DataControlRowState, ByVal IncludeReadOnly As Boolean)
            Dim oControl As Control = Nothing
            Dim sDataField As String = Me.DataField
            Dim oFieldValue As Object = Nothing

            If (Cell.Controls.Count > 0) Then
                oControl = Cell.Controls.Item(0)
                Dim oCheckBox As CheckBox = TryCast(oControl, CheckBox)
                If ((Not oCheckBox Is Nothing) AndAlso (IncludeReadOnly OrElse oCheckBox.Enabled)) Then
                    If Me.DefineValue = String.Empty Then
                        oFieldValue = oCheckBox.Checked
                    Else
                        oFieldValue = BooleanToValue(oCheckBox.Checked)
                    End If
                End If
            End If

            If (Not oFieldValue Is Nothing) Then
                If Dictionary.Contains(sDataField) Then
                    Dictionary.Item(sDataField) = oFieldValue
                Else
                    Dictionary.Add(sDataField, oFieldValue)
                End If
            End If
        End Sub

    End Class
End Namespace